!

+++++++++++++++++++++++++++++
!APDL-Flambagem Torsional
!+++++++++++++++++++++++++++++
finish
/clear,nostart
/filname,flambagem-torsional
/TITLE,Flambagem-Torsional
/REP,FAST
/UIS,MSGPOP,4 !Suprime mensagens de erro
keyw,pr_sgui,1 !Suprime Solution is done.
!+++++++++++++++++++++
!Dimenses do elemento
!+++++++++++++++++++++
vao=1700
ABA1=38.1 !(base da cantoneira)
ABA2=38.1 !(altura da cantoneira)
t=3.18 !(espessura da cantoneira)
DESLOCTOTAL=vao/666.6666666666666666
DESLOC1=vao/2000
*SET,b,(ABA1-0.5*t)
*SET,d,(ABA2-0.5*t)
*SET,centx,(0.5*t*(d*t)+(0.5*(b-t)+t)*(b*t-t**2))/(d*b-(d-t)*(b-t))
*SET,centz,(0.5*t*b*t+(0.5*(d-t)+t)*(d-t)*t)/(d*b-(d-t)*(b-t))
!++++++++++++++++
!Diviso da Malha
!++++++++++++++++
div_secao=5 !(nmero de divises da malha do modelo referentes a seo)
div_compr=vao/100 !(nmero de divises da malha do modelo referentes ao comprimento
da coluna)
!++++++++++++++++++++++++++
!Propriedades do Material
!++++++++++++++++++++++++++
/prep7
ET,1,SHELL181
!sect,1,shell,,
!secdata, t,1,0.0,3
MP,EX,1,200000 !Mdulo de Elasticidade do Ao
MP,EY,1,200000 !Mdulo de Elasticidade do Ao
MP,EZ,1,200000 !Mdulo de Elasticidade do Ao
MP,PRXY,1,0.3 !Coeficiente de Poisson do Ao
MP,GXY,1,77000 !Mdulo de Elasticidade Transversal
MP,GXZ,1,77000 !Mdulo de Elasticidade Transversal
MP,GYZ,1,77000 !Mdulo de Elasticidade Transversal
TB,BISO,1,1,2, !Define o comportamento do grfico tenso x deformao
TBTEMP,0 !Define uma temperatura para o material
TBDATA,,250,10,,,, !Define a tenso de escoamento
R,1,t,t,t,t
!++++++++++++++++++++
!Montagem do Elemento
!++++++++++++++++++++
/VIEW,1,1,1,1
/ANG,1
k,1,b,0,0
k,2,0,0,0
k,3,0,vao,0
k,4,b,vao,0
k,5,0,0,d
k,6,0,vao,d
*DO,I,1,3
L,I,I+1
*ENDDO
L,4,1
*DO,I,2,3
L,I,I+3
*ENDDO
L,5,6
AL,1,2,3,4
AL,2,5,6,7
!+++++++++++++++++
!Montagem da Malha
!+++++++++++++++++
LESIZE,1,,,div_secao
LESIZE,3,,,div_secao
LESIZE,5,,,div_secao
LESIZE,6,,,div_secao
LESIZE,2,,,div_compr
LESIZE,4,,,div_compr
LESIZE,7,,,div_compr
REAL,1
AMESH,all
EPLOT
!++++++++++++++++++++
!Criao do Centride
!++++++++++++++++++++
*GET,NODMAX,NODE,,COUNT
NN1=NODMAX+1
NN2=NODMAX+2
N,NN1,centx,0,centz ! gera no no centro da coluna
N,NN2,centx,vao,centz ! gera no no centro da coluna
NPLOT
LSEL,S,LOC,Y,vao,vao ! seleciona a linha do topo da coluna
NSLL,S,1 ! seleciona os nos pertencentes a essa linha
CM,NODES_UP,NODE ! nomeia esses nos
LPLOT
allsel
LSEL,S,LOC,Y,0,0 ! seleciona a linha da base da coluna
NSLL,S,1 ! seleciona os nos pertencentes a essa linha
CM,NODES_DOWN,NODE ! nomeia esses nos
allsel
LPLOT
ET,2,MASS21 ! cria elemento de massa
TYPE,2
R,2,0,0,0,0,0,0,
REAL,2
e,NN1 ! define elemento por conectividade de no
e,NN2
cmsel,s,NODES_UP ! Seleciona os Ns do NODES_UP
nsel,a,,,NN2 ! adiciona a selecao o n NN2
cerig,NN2,all ! define uma regiao rigida
allsel
cmsel,s,NODES_DOWN ! Seleciona os Ns do NODES_DOWN
nsel,a,,,NN1 ! adiciona a selecao o n NN1
cerig,NN1,all ! define uma regiao rigida
allsel
FINISH ! Fecha /PREP7
!++++++++++++++++++++
!Criao dos Apoios
!++++++++++++++++++++
/SOLU
ANTYPE,STATIC
PSTRES,ON
D,NN1,,,,,,uy,ux,uz,rotz,roty,
D,NN2,,,,,,ux,uz,rotz,roty,
!DDELE,NN2,UY
EPLOT
!++++++++++++++++++++++++++++++
!Aplicao da Carga no Elemento
!++++++++++++++++++++++++++++++
F,NN2,FY,-1
EPLOT
SOLVE
FINISH
!++++++++++++++++++++
!Anlise de Flambagem
!++++++++++++++++++++
/SOLU
ANTYPE,BUCKLE
BUCOPT,LANB,3
SOLVE
FINISH
/SOLU
EXPASS,ON
MXPAND,3
SOLVE
FINISH
/POST1
!SET,LIST
SET,LAST
/VIEW,1,1,1,1
/ANG,1
/REP,FAST
PLDISP