UNIVERSIDAD DE EL SALVADOR

FACULTAD DE INGENIERA Y ARQUITECTURA

ESCUELA DE INGENIERA ELCTRICA
ANLISIS ELCTRICO I
CICLO I - 2017

Catedrtico: Ing. Gerardo Marvin Jorge Hernndez.

Instructores: Br. Cristian Antonio Aguilar Quintanilla.
Br. Diego Fernando Guidos Espinoza

Uso de Barrido en DC, Verificacin del Teorema de Thevenin y Sub-circuitos.

Barrido en DC.

El barrido en DC tambin se conoce como caracterstica de transferencia de DC. La variable

de entrada vara en un rango de valores. Para cada valor de las variables de entrada, el punto
de funcionamiento de DC y la ganancia de DC de pequea seal se calculan llamando a la
capacidad de funcin de transferencia de pequea seal de SPICE OPUS.

La sintaxis general para realizar este tipo de anlisis es:

dc parmetros valor inicial valor de paro valor de paso

Todos los elementos del anlisis de barrido en DC deben especificarse en minscula; aunque
en la declaracin de los parmetros del circuito estn en mayscula.

Otra instruccin utilizada frecuentemente es:

destroy all

La cual limpia el rea de trabajo y la memoria de operacin de SPICE OPUS.

En la Gua de Simulacin I se vio un ejemplo de cmo utilizar este tipo de anlisis aplicado
al Teorema de Mxima Transferencia de Potencia (T.M.T.P.); ahora se tratar un caso
distinto, en el cual se graficar la caracterstica Vo/Vi de un circuito para distintos valores de
un parmetro que se cambiar automticamente sin estar corrigiendo una lnea de cdigo.

Ejemplo. Para el circuito mostrado, calcular y graficar la ganancia de voltaje Vo vs. Vi. El
voltaje de entrada vara desde 0 hasta 100 mV, en pasos de 2 mV. La resistencia de carga
vara desde 10 k hasta 30 k en pasos de 10 k.
Cdigo en SPICE OPUS:

* Ejemplo 1.
* Gua Anexo I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

Vs 1 0 DC 100m
Vx 2 3 DC 0
* Fuentes de corriente dependiente de corriente.
f1 5 4 Vx 100
* Resistencias.
RL 5 0 10k
RS 1 2 500
R1 2 0 15k
rp 3 4 1.5k
RE 4 0 250
ro 5 4 50k
.control
destroy all
dc vs 0 100m 2m
alter rl=20k
dc vs 0 100m 2m
alter rl=30k
dc vs 0 100m 2m
plot dc1.V(5) dc2.V(5) dc3.V(5)
+ xlabel 'Vs [V]'
+ ylabel 'Vo [V] para RL=10 kOhm [roja]
+ RL=20 kOhm [verde]
+ RL=30 kOhm [azul]'
.endc
.end

Verificacin del Teorema de Thevenin.

Cualquier red bilateral lineal conectada a los terminales A y B puede ser reemplazada por
una fuente de voltaje de valor igual al voltaje de circuito abierto VOC entre los terminales A
y B conectados en serie con una impedancia interna Z TH. Donde ZTH, es la impedancia
equivalente del circuito medida desde los terminales A y B con todas las fuentes
independientes en el circuito reducidas a cero. Se tiene adems que Z TH = VOC/ISC, donde ISC
es la corriente de cortocircuito que fluye entre A y B.
Para resolver un problema de este tipo en SPICE OPUS hay dos mtodos: (i) Usando el
comando tf, y (ii) Usando la ecuacin ZTH = VOC/ISC.

La capacidad de funcin de transferencia de pequea seal de SPICE OPUS se puede utilizar

para encontrar la ganancia de DC de pequea seal (transfer_function), la resistencia de
entrada (input_impedance) y la resistencia de salida (output_impedance) de un circuito.

La sintaxis general para realizar este tipo de anlisis es:

tf nodo de salida nodo de entrada

Ejemplo. Para el circuito mostrado se conecta una resistencia de 2 entre los terminales A
y B determinar el equivalente Thevenin del circuito visto por la resistencia.

* Ejemplo 2 Forma 1.
* Gua Anexo I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

V1 1 0 DC 2
V2 3 0 DC 4
* Fuente de tensin Thevenin.
Voc 4 0 DC 0
* Resistencias.
R1 1 2 2
R2 2 0 12
R3 2 a 1
R4 a 3 3
R5 5 0 2
* Resistencia Thevenin. Valor inicial asumido.
Rth 4 5 10
.control
destroy all
* Anlisis de transferencia.
tf v(a) v1
tf v(a) v2
* Creando nuevas variables.
let ocv=(tf1.transfer_function*@v1+tf2.transfer_function*@v2)
let zth=output_impedance
echo La solucin usando el comando tf es:
echo
echo Voc es:
print ocv
echo
echo Rth es:
print zth
echo
* Para determinar la corriente que llega a R5.
alter voc=ocv
alter rth=zth
op
let i2Ohm=-i(Voc)
echo La corriente en la resistencia R5 es:
print i2Ohm
echo
.endc
.end

La segunda forma consiste en encontrar VOC en primer lugar. Usando un interruptor

controlado por voltaje para causar un cortocircuito para medir I SC.

El interruptor controlado por voltaje se declara utilizando un modelo y la declaracin es la

siguiente:

Snombre Nodo + Nodo - Nodo de control + Nodo de control Nombre modelo

 Vcontrol Nodo de control + Nodo de control {Tipo de fuente}

.model Snombre SW (VT=XX VH=XX RON=XX ROFF=XX)

VT = Voltaje de umbral. Voltaje de control en estado encendido.

VH = Voltaje de histresis. Voltaje de control en estado apagado.
RON = Resistencia cuando el interruptor est apagado.
ROFF = Resistencia cuando el interruptor esta encendido.

La dificultad debida a la alta ganancia de un conmutador ideal se puede minimizar eligiendo

el valor de ROFF para que sea tan alto como sea permisible y el de R ON sea tan bajo como sea
posible en comparacin con otros elementos de circuito, dentro de los lmites de la precisin
permisible.
* Ejemplo 2 Forma 2.
* Guia Anexo I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

V1 1 0 DC 2
V2 3 0 DC 4
Vcontrol 5 0 DC 0
Vx 4 0 DC 0
* Asumiendo un valor inicial para Voc.
Voc 6 0 DC 0
* Interruptor controlado por voltaje.
S1 a 4 5 0 SMOD
.model SMOD SW ( VT=0.001 VH=0.001 RON=0.001 ROFF=10e5 )
* Resistencias.
R1 1 2 2
R2 2 0 12
R3 2 a 1
R4 3 a 3
* Puesta para evitar errores con el programa, se puede obviar.
R5 5 0 10Meg
R6 7 0 2
* Valor asumido.
Rth 6 7 10
.control
destroy all
*Inicialmente el interruptor est abierto. Determinamos Voc.
op
echo
echo Voc es:
print v(a)
* Cambiando el valor de Vcontrol para superar VT y producir un cortocircuito.
alter vcontrol=10
op
echo
echo Isc es:
print i(Vx)
echo
echo Rth=Voc/Isc es:
let zth=op1.v(a)/op2.i(Vx)
print zth
alter voc=op1.v(a)
alter rth=op1.v(a)/op2.i(Vx)
op
echo
let i2Ohm=-i(Voc)
echo La corriente en la resistencia R5 es:
print i2Ohm echo
.endc
.end

Sub-circuitos.

Un sub-circuito permite definir un bloque de circuitos y luego utilizar ese bloque en varios
lugares. La forma general para la definicin de sub-circuito (o descripcin) es

.SUBCKT SUBNOMBRE [ (dos o ms) nodos ]

Para llamar a un sub-circuito se utiliza una X. La forma general para llamarlos es:

Xnombre [ (dos o ms) nodos ] SUBNOMBRE

Los sub-circuitos pueden estar anidados. Es decir, el sub-circuito A puede llamar a otros sub-
circuitos. Pero el anidamiento no puede ser circular, lo que significa que, si el sub-circuito A
contiene una llamada al sub-circuito B, el sub-circuito B no debe contener una llamada al
sub-circuito A. Debe haber el mismo nmero de nodos en la declaracin de sub-circuito como
en su definicin. La definicin de sub-circuito debe contener slo declaraciones de elementos
(sentencias sin un punto) y puede contener instrucciones .model.

En muchas aplicaciones es conveniente utilizar un parmetro en lugar de un valor numrico,

de tal manera que el parmetro pueda combinarse en expresiones aritmticas. La definicin
del parmetro es, seguida de ejemplos:

.param [Pnombre=Valor o (expresin)]

.param Vfuente = 12V
.param Anchodebanda = {50kHz/5}
.param PI = 3.1415

Se utilizan as:

Vcc 1 0 DC {Vfuente}

Ejemplo. Para el Ejemplo 7 de la Gua de Simulacin I, cambiar el A.O., el cual es ideal por
el del LM741 y aumentar V1 a 10 V. Sera necesario agregar la alimentacin del A. O., estas
sern VDD = 15 VDC y VSS = -15 VDC.

* Ejemplo 3.
* Gua Anexo I.
* AEL115 Ciclo I-2017.

* Fuentes de tensin independientes.

V1 1 2 DC 10
Vx 5 6 DC 0
VDD 7 0 DC 15
VSS 8 0 DC -15
* Amplificadores Operacionales.
*EXX <Nodo de Salida> <Nodo de referencia> <Entrada no Inversora, V+>
* + <Entrada Inversora, V-> <Ganancia de lazo abierto>
*E1 6 0 0 4 10Meg
*XAMP <Entrada no inversora> <Entrada inversora> <Alimentacin Positiva>
* + <Alimentacin Negativa> <Nodo de Salida> <Nombre AO>
XAMP1 0 4 7 8 6 LM741/NS
* Resistencias.
R1 1 3 10k
R2 3 2 30k
R3 1 4 30k
R4 2 4 10k
R5 3 5 30k
R6 3 0 10k
R7 5 0 30k
*XAMP <Entrada no inversora> <Entrada inversora> <Alimentacin Positiva>
* + <Alimentacin Negativa> <Nodo de Salida> <Nombre AO>
*//////////////////////////////////////////////////////////
*LM741 OPERATIONAL AMPLIFIER MACRO-MODEL
*//////////////////////////////////////////////////////////
*
* connections: non-inverting input
* | inverting input
* | | positive power supply
* | | | negative power supply
* | | | | output
* | | | | |
* | | | | |
.SUBCKT LM741/NS 1 2 99 50 28
*
*********** Features:
*********** Improved performance over industry standards
*********** Plug-in replacement for LM709,LM201,MC1439,748
*********** Input and output overload protection
***********
*************************** Etapa de Entrada
***********************************
***********
***********
IOS 2 1 20N
*^Corriente de desnivel en la entrada
R1 1 3 250K
R2 3 2 250K
I1 4 50 100U
R3 5 99 517
R4 6 99 517
Q1 5 2 4 QX
Q2 6 7 4 QX
*Fp2=2.55 MHz
C4 5 6 60.3614P
***********
***********
*********************** Efecto de Modo Comun
***********************************
***********
***********
I2 99 50 1.6MA
*^Quiescent supply current
EOS 7 1 POLY(1) 16 49 1E-3 1
*Voltaje de desnivel en la entrada^
R8 99 49 40K
R9 49 50 40K
***********
***********
*********************** Limite del voltaje de salida ***************************
***********
***********
V2 99 8 1.63
D1 9 8 DX
D2 10 9 DX
V3 10 50 1.63
***********
***********
******************************* Segunda Etapa
**********************************
***********
***********
EH 99 98 99 49 1
G1 98 9 5 6 2.1E-3
*Fp1=5 Hz
R5 98 9 95.493MEG
C3 98 9 333.33P
***********
***********
****************************** Etapa del polo
**********************************
***********
***********
*Fp=30 MHz
G3 98 15 9 49 1E-6
R12 98 15 1MEG
C5 98 15 5.3052E-15
***********
***********
************************* Etapa del cero en modo comun
*************************
***********
***********
*Fpcm=300 Hz
G4 98 16 3 49 3.1623E-8
L2 98 17 530.5M
R13 17 16 1K
***********
***********
************************* Etapa de salida
**************************************
***********
***********
F6 50 99 POLY(1) V6 450U 1
E1 99 23 99 15 1
R16 24 23 25
D5 26 24 DX
V6 26 22 0.65V
R17 23 25 25
D6 25 27 DX
V7 22 27 0.65V
V5 22 21 0.18V
D4 21 15 DX
V4 20 22 0.18V
D3 15 20 DX
L3 22 28 100P
RL3 22 28 100K
***********
***********
************************* Modelos del subcircuito
******************************
***********
***********
.MODEL DX D(IS=1E-15)
.MODEL QX NPN(BF=625)
***********
***********
.ENDS
***********
***********
.control
op
echo
echo La tensin de salida Vo es:
echo
print V(5)
echo
echo La corriente io es:
print i(Vx)
echo
.endc
.end

Porque no es el resultado esperado?